• → $OutputForms

$BoxForms

$BoxForms

contains the current list of general-purpose “BoxForms” formatters.

Elements of $BoxForms are valid forms to be used as a second parameter in MakeBoxes expressions.

Adding a new MakeBoxes rule does not automatically extend the $BoxForms list as happens, for example, in $PrintForm when new FormatValues are defined.

To see how to add a new form, let us first list the values defined in $Boxforms. This will be useful to compare against later:

• • $BoxForms

Now we add a rule with our new form MyBoxForm:

• • MakeBoxes[x_Integer, MyBoxForm] := StringJoin[Table["o",{x}]]

Although a rule involving MyBoxForm has been defined in MakeBoxes, the rule is not triggered in boxing.

• • MyBoxForm[3]

And it is not defined in $BoxForms either:

• • $BoxForms

To have MyBoxForm formatting take effect in boxing via MakeBoxes, we first need to add the new form to $BoxForms:

• • AppendTo[$BoxForms, MyBoxForm]

This automatically stores the new form in $PrintForms and $OutputForms:

• • MemberQ[$PrintForms, MyBoxForm]

• • MemberQ[$OutputForms, MyBoxForm]

We also need to define in MyBoxForm its ParentForm:

• • Unprotect[ParentForm];ParentForm[MyBoxForm]=TraditionalForm

Now,

• • MyBoxForm[3]

The ParentForm is used when a MakeBoxes rule for a given expression is not available:

• • MyBoxForm[F[3]]

Above, the MyBoxForm rule is not used to format the argument, because the rule used to format the expression propagates TradionalForm (the ParentForm of our custom BoxForm) to the arguments.

To fix this, define a rule that propagates the box form to its elements:

• • MakeBoxes[head_[elements___],MyBoxForm] := RowBox[{MakeBoxes[head,MyBoxForm], "<", RowBox[MakeBoxes[#1, MyBoxForm]&/@{elements}]     ,">"}]

Now,

• • MyBoxForm[F[3]]

Suppose now we want to remove the new BoxForm. We can reset $BoxForms to its default values by unset it:

• • $BoxForms=.; $BoxForms

This does not remove the value from $PrintForm or $OutputForm:

• • {MemberQ[$PrintForms, MyBoxForm], MemberQ[$OutputForms, MyBoxForm]}

To remove MyBoxForm, unset in each variable:

• • $PrintForms=.; $OutputForms=.;

• • {MemberQ[$PrintForms, MyBoxForm], MemberQ[$OutputForms, MyBoxForm]}